// POV-Ray 3.6 Scene File "vcross_r.pov"
// right handed coordinate system

// Author: Friedrich A. Lohmueller, 2005
// email: Friedrich.Lohmueller_at_t-online.de
// homepage: http://wwww.f-lohmueller.de
//
//------------------------------------------------------------------------
#version 3.6;
global_settings {  assumed_gamma 1.0 }
//------------------------------------------------------------------------
#include "colors.inc"
#include "textures.inc"
#include "glass.inc"
#include "metals.inc"
#include "golds.inc"
#include "stones.inc"
#include "woods.inc"
#include "shapes.inc"
#include "shapes2.inc"
#include "functions.inc"
#include "math.inc"          
#include "transforms.inc"
//------------------------------------------------------------------------
#declare Camera_0 = camera {                                // xy view
                             angle 18
                             right    -x*image_width/image_height
                             sky <0,0,1>                                // right handed!!!!!!!!
                             location  <20.0, 20.0, 20.0>
                             look_at   <0.0, 0.0, 0.5>
                           }

#declare Camera_1 = camera {                                // diagonal view
                             angle 18
                             right    -x*image_width/image_height
                             sky <0,0,1>                                // right handed!!!!!!!!
                             location  <4.0, -8.0,  5.0 + 1>
                             look_at   <0.0, 0.0, 0.0 + 1>
                           }

camera{Camera_1}

//------------------------------------------------------------------------
// sun -------------------------------------------------------------------
//light_source{<1500, 2500, 2500> color White}
light_source{<-1500, -1500, 2500> color White}
light_source{<-1500, -1500, -2500> color White}

// sky -------------------------------------------------------------------
sky_sphere{ pigment{ gradient <0,1,0>
                     color_map{ [0   color rgb<1,1,1>         ]//White
                                [0.4 color rgb<1,1,1>]//~Navy
                                [0.6 color rgb<1,1,1>]//<0.14,0.14,0.56>]//~Navy
                                [1.0 color rgb<1,1,1>         ]//White
                              }
                     scale 2 }
           } // end of sky_sphere 
//------------------------------------------------------------------------

//------------------------------ the Axes --------------------------------
//------------------------------------------------------------------------
#macro Axis_( AxisLen, Dark_Texture,Light_Texture) 
 union{
    cylinder { <0,-AxisLen,0>,<0,AxisLen,0>,0.025
               texture{checker texture{Dark_Texture } 
                               texture{Light_Texture}
                       translate<0.1,0,0.1>}
             }
    cone{<0,AxisLen,0>,0.1,<0,AxisLen+0.5,0>,0
          texture{Dark_Texture}
         }
     } // end of union                   
#end // of macro "Axis()"
//------------------------------------------------------------------------
#macro AxisXYZ( AxisLenX, AxisLenY, AxisLenZ, Tex_Dark, Tex_Light)
//--------------------- drawing of 3 Axes --------------------------------
union{
#if (AxisLenX != 0)
 object { Axis_(AxisLenX, Tex_Dark, Tex_Light)   rotate< 0,0,-90> no_shadow }// x-Axis
 text   { ttf "arial.ttf",  "x",  0.15,  0  texture{Tex_Dark} 
          rotate< 90, 0, 0> scale 0.5 translate <AxisLenX+0.75, 0.0, 0.0>}
#end // of #if 
#if (AxisLenY != 0)
 object { Axis_(AxisLenY, Tex_Dark, Tex_Light)   rotate< 0,0,  0> no_shadow }// y-Axis
 text   { ttf "arial.ttf",  "y",  0.15,  0  texture{Tex_Dark}    
          rotate< 90, 0, 0>  scale 0.5 translate < 0.0,AxisLenY+0.5,0.0>}
#end // of #if 
#if (AxisLenZ != 0)
 object { Axis_(AxisLenZ, Tex_Dark, Tex_Light)   rotate<90,0,  0> no_shadow }// z-Axis
 text   { ttf "arial.ttf",  "z",  0.15,  0  texture{Tex_Dark}
          rotate< 90, 0, 0>  scale 0.5 translate < 0.0,0.0,AxisLenZ+0.75>}
#end // of #if 
} // end of union
#end// of macro "AxisXYZ( ... )"
//------------------------------------------------------------------------

#declare Texture_A_Dark  = texture {
                               pigment{color rgb<1,0.25,0>}
                               finish {ambient 0.15 diffuse 0.85 phong 1}
                             }
#declare Texture_A_Light = texture { 
                               pigment{color rgb<0.8,0.8,0.8>}
                               finish {ambient 0.15 diffuse 0.85 phong 1}
                             }

//object{ AxisXYZ( 3.0, 3.0, 3.0, Texture_A_Dark, Texture_A_Light)} // <<<<<<<<<<<<<<<<< adapt the axes here !!!
object{ AxisXYZ( 3.0, 3.0, 3.0, Texture_A_Dark, Texture_A_Light)} // <<<<<<<<<<<<<<<<< adapt the axes here !!!

//-------------------------------------------------- end of coordinate axes


// ground -----------------------------------------------------------------
//---------------------------------<<< settings of squered plane dimensions
#declare RasterScale = 1.0/5;
#declare RasterHalfLine  = 0.035 ;  
#declare RasterHalfLineZ = 0.035 ; 
//-------------------------------------------------------------------------
#macro Raster(RScale, HLine) 
       pigment{ gradient x scale RScale
                color_map{[0.000   color rgbt<1,1,1,1>*0.4]
                          [0+HLine color rgbt<1,1,1,1>*0.4]
                          [0+HLine color rgbt<1,1,1,1>]
                          [1-HLine color rgbt<1,1,1,1>]
                          [1-HLine color rgbt<1,1,1,1>*0.4]
                          [1.000   color rgbt<1,1,1,1>*0.4]} }
       finish { ambient 0.15 diffuse 0.85}
 #end// of Raster(RScale, HLine)-macro    
//-------------------------------------------------------------------------
    

plane { <0,0,1>, 0    // plane with layered textures
        texture { pigment{color rgbt<1,1,1,0.7>*1.1}
                  finish {ambient 0.45 diffuse 0.85}}
        texture { Raster(RasterScale,RasterHalfLine ) rotate<0,0,0> }
        texture { Raster(RasterScale,RasterHalfLineZ) rotate<0,0,90>}
        rotate<0,0,0>
        no_shadow
      }
//------------------------------------------------ end of squered plane XZ

//--------------------------------------------------------------------------
//---------------------------- objects in scene ----------------------------
//--------------------------------------------------------------------------
#default{ finish {ambient 0.15 diffuse 0.85} } // 


// 
//------------------------------------------------------------------------------------
#include "analytical_g.inc" 
//------------------------------------------------------------------------------------
// ----------------------------------------------------------------------------------- 

// ----------------------------------------------------------------------------------- 
// ---------------------  Punti e Vettori  - Punkte und Vektoren -  Points and Vectors
//------------------------------------------------------------------------------------
                            
                            
///////////////////////////////
                            
 
#declare O  =  < 0, 0, 0>;  
#declare px = 0.5;
#declare py = 0.5;
#declare P =  <px, py, 0>;  
#declare P1 =  <1, 0, -1>;

#declare Rs = 0.03;   // sphere
#declare Rc = 0.01;   // cylinder


//#declare Sphere_1 = sphere {
//        P, 1.0
//        pigment{ color Yellow transmit 0.8 }
//        finish {ambient 0.1 diffuse 0.8 phong 1}
//}  


#declare Sphere_1 = sphere {
        P, 1.0
        pigment{color Silver transmit 0.5}
        finish {ambient 0.1 diffuse 0.8 phong 1}
}

// hyperboloid                
#declare a = 0.5;
#declare b = a;
#declare c = 1.0;
#declare Hyperboloid_1 = quadric { 
  <1/(a*a),1/(b*b),-1/(c*c)>,<0,0,0>,<0,0,0>,1
  clipped_by { plane { <0, 0, 1>, 2 } }
  clipped_by { plane { <0, 0, -1>, 0 } }

  pigment{color Red transmit 0.5}
  finish {ambient 0.1 diffuse 0.8 phong 1}  
}

// cone
#declare Cone_1 = cone {
  O, 0, <0, 0, 2>, a*2
  open
  pigment{color Yellow transmit 0.5}
  finish {ambient 0.1 diffuse 0.8 phong 1}  
}

#declare Cone_2 = cone {
  O, 0, <0, 0, 2>, a*2
  open
}

// z = c plane
#declare Plane_c = plane {
   <0, 0, 1>, c
//  clipped_by { box { <-1, -1, 0>, <1, 1, 3> } }
   clipped_by { Cone_2 }

  pigment{color Blue transmit 0.5}
  finish {ambient 0.1 diffuse 0.8 phong 1}  
}

// z = 0 plane                     
#declare N = <0, 0, 1>;
#declare Pp = <0, 0, 0.005>;                    
#declare Plane_1 = object{
 Plane_NoP(  N, Pp, <-3,-3,-3>, <3,3,3> )
 pigment{ color rgbt<0, 1.0, 0.6, 0.2> }
}



#declare P1N = <0,0,0>;
#declare P1 = trace( Hyperboloid_1, P, <px, py, 1>-P, P1N );

#declare Q1N = <0,0,0>;
#declare Q1 = trace( Plane_c, P1, <0,0,0>-P1, Q1N);         

#declare Q = <Q1.x, Q1.y, 0>;


#declare Text_P = text {
  ttf "arial.ttf",  "P",  0.01,  0
  texture{Texture_A_Dark}
  rotate< 90, 0, 0> scale 0.15 translate P+<0.05,0.05,0.05>
}

#declare Text_P1 = text { 
  ttf "arial.ttf",  "P'",  0.01,  0
  texture{Texture_A_Dark}
  rotate< 90, 0, 0> scale 0.15 translate P1+<0.05,0.05,0.05>
}

#declare Text_Q1 = text {
  ttf "arial.ttf",  "Q'",  0.01,  0
  texture{Texture_A_Dark}
  rotate< 90, 0, 0> scale 0.15 translate Q1+<0.05,0.05,0.05>
}

#declare Text_Q = text {
  ttf "arial.ttf",  "Q",  0.01,  0
  texture{Texture_A_Dark}
  rotate< 90, 0, 0> scale 0.15 translate Q+<0.05,0.05,0.05>
}



            
union{

sphere{ P , Rs   pigment{ color Red } no_shadow }
object{ Text_P }

sphere{ P1, Rs   pigment{ color Red } no_shadow }
object{ Text_P1 }

object{ Vector( P, P1, Rc) pigment{ color White } no_shadow }      


sphere{ Q1, Rs   pigment{ color Red } no_shadow }
object{ Text_Q1 }

object{ Vector( P1, O, Rc) pigment{ color White } no_shadow }      

sphere{ Q , Rs   pigment{ color Red } no_shadow }
object{ Text_Q }

object{ Vector( Q1, Q, Rc) pigment{ color White } no_shadow }      

//sphere{ I1, Rs   pigment{ color Orange }}
object{ Hyperboloid_1 no_shadow } 
object{ Cone_1 no_shadow } 
object{ Plane_c no_shadow }
//object{ Plane_1 } 

 
}

// ------------------------------------------------------------------------------------------------------- end