SubApplication subclass: #DhbEstimationChi2
    instanceVariableNames: ''
    classVariableNames: ''
    poolDictionaries: ''!



!DhbHistogram publicMethods !

chi2Against: aScaledDistribution
		"(c) Copyrights Didier BESSET, 2000, all rights reserved.
		 Initial code: 1/30/00 "
	| chi2 |
	chi2 := 0.
	self pointsAndErrorsDo:
		[ :each | chi2 := ( each chi2Contribution: aScaledDistribution) + chi2].
	^chi2!

chi2ConfidenceLevelAgainst: aScaledDistribution
		"(c) Copyrights Didier BESSET, 2000, all rights reserved.
		 Initial code: 1/30/00 "
	^( DhbChiSquareDistribution degreeOfFreedom: ( contents size - aScaledDistribution parameters size))
			confidenceLevel: ( self chi2Against: aScaledDistribution)!

pointsAndErrorsDo: aBlock
		"
		 (c) Copyrights Didier BESSET, 1999, all rights reserved.
		 Initial code: 11/3/99 "
	| x |
	x := self minimum - ( self binWidth / 2).
	contents do:
		[ :each |
		  x := x + self binWidth.
		  aBlock value: ( DhbWeightedPoint point: x count: each).
		].! !

!DhbStatisticalMoments publicMethods !

asWeightedPoint: aNumber
		"(c) Copyrights Didier BESSET, 2000, all rights reserved.
		 Initial code: 2/5/00 "
	^DhbWeightedPoint point: aNumber @ self average error: self errorOnAverage! !

DhbEstimationChi2 initializeAfterLoad!